springboot 3 + java17 QueryDSL gradle 파일

1. build.gradle 파일 수정

기존 gradle 부분에 [추가] 부분을 추가하면 된다

//[추가start]
buildscript {
    ext {
        queryDslVersion = "5.0.0"
    }
}
//[추가end]

plugins {
	id 'java'
	id 'org.springframework.boot' version '3.3.4'
	id 'io.spring.dependency-management' version '1.1.6'
}

group = 'com.example'
version = '0.0.1-SNAPSHOT'

java {
	toolchain {
		languageVersion = JavaLanguageVersion.of(17)
	}
}

repositories {
	mavenCentral()
}

dependencies {
	implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
	implementation 'org.springframework.boot:spring-boot-starter-web'
	implementation 'org.springframework.boot:spring-boot-starter-security'
	// JWT Dependencies
    implementation 'io.jsonwebtoken:jjwt-api:0.11.5'
    implementation 'org.modelmapper:modelmapper:3.1.0'
    implementation 'com.fasterxml.jackson.datatype:jackson-datatype-jsr310:2.15.2'
    runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.11.5'
    runtimeOnly 'io.jsonwebtoken:jjwt-jackson:0.11.5'
	runtimeOnly 'com.mysql:mysql-connector-j'
	testImplementation 'org.springframework.boot:spring-boot-starter-test'
	testImplementation 'io.projectreactor:reactor-test'
	testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
	compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'
	implementation group: 'org.json', name: 'json', version: '20240303'
	//[추가start]
	implementation "com.querydsl:querydsl-jpa:${queryDslVersion}:jakarta"
	implementation "com.querydsl:querydsl-apt:${queryDslVersion}:jakarta"
	annotationProcessor(
		"com.querydsl:querydsl-apt:${queryDslVersion}:jakarta",
		"jakarta.annotation:jakarta.annotation-api",
		"jakarta.persistence:jakarta.persistence-api"
	)
    //[추가end]
}

tasks.named('test') {
	useJUnitPlatform()
}

//[추가start]
def querydslDir = "src/main/generated"

sourceSets {
    main.java.srcDir querydslDir
}

tasks.withType(JavaCompile) {
    options.annotationProcessorGeneratedSourcesDirectory = file(querydslDir)
}

clean {
    delete file(querydslDir)
}
//[추가end]

 

 

 

2. 프로젝트 gradle refresh

 

 

 

3. Gradle Tasks > build 실행

 

안보이면 Window > Show View > Other > Gradle Tasks [Open]

 

 

4. 프로젝트 새로고침해서 생성된 QEntity.java 확인

 

 

안되면 gradle clean 이나 :compileJava 해준다.